$PROBLEM ESTIMATE DATA WITH NO CP OR JD
$INPUT ID TIME OLDT TDOS PAE DV IND1
 
$DATA nmdata100indest.csv IGNORE=#  ;ACCEPT=(ID.GT.1)  
$PRED
IND1A=IND1
IF (NEWIND.NE.2) THEN
   SW1A=0
  ; PAE=0
   FLG1=0
ENDIF 
;TIME TO FIRST AE STRUCTURAL PART
   ;WEIBULL FAILURE PARAMETER
   ALPH1=THETA(1)
   ALPH1C=THETA(2)
   GAM1=THETA(6)
   MED1=THETA(3)*(1-TDOS**GAM1*THETA(4)/(THETA(5)**GAM1+TDOS**GAM1))
   IF (MED1.LE.0) THEN
      PRINT MED1
      EXIT 1 100
   ENDIF
   LAM1=0.693/MED1**ALPH1
    CP1=THETA(7)
   IF (TIME.LE.CP1) THEN
      H1ZT1=LAM1*TIME**ALPH1
      H1ZT0=LAM1*OLDT**ALPH1
   ELSE
      H1ZT1=LAM1*TIME**ALPH1C*CP1**(ALPH1-ALPH1C)
      H1ZT0=LAM1*OLDT**ALPH1C*CP1**(ALPH1-ALPH1C)
   ENDIF

   I1HAZ=H1ZT1-H1ZT0
   Q1=EXP(-I1HAZ)
   ;NEED PREVIOUS DV HERE
   ;MC PART
   ; baseline values for severity (logit)
   IF (PAE.EQ.0) THEN
      B11=THETA(8)
      B12=B11+THETA(9)
      B13=B12+THETA(10)
   ENDIF 

   IF(PAE.EQ.1) THEN
     B11=THETA(11)
     B12=B11+THETA(12)
     B13=B12+THETA(13)
     EMAX=0
   ENDIF
   IF(PAE.EQ.2) THEN
     B11=THETA(14)
     B12=B11+THETA(15)
     B13=B12+THETA(16)
     EMAX=0
   ENDIF

   IF(PAE.EQ.3) THEN
     B11=THETA(17)
     B12=B11+THETA(18)
     B13=B12+THETA(19)
     EMAX=0
   ENDIF

   
   RESP=0                
   ;-----------------------------------------------------
                  ; INTERSUBJECT VARIABILITY
  IF (ETA(1).GE.0) THEN
     ET1 = ((ETA(1)+1)**THETA(20)-1)/THETA(20)
  ELSE
     ET1 = -((1-ETA(1))**THETA(20)-1)/THETA(20)
  ENDIF
  ;ET1=ETA(1) 
   
  
   
   ;-----------------------------------------------------
   ; logits for Y>=1, Y>=2, Y.=3
   A11 = B11 + ET1
   A12 = B12 + ET1
   A13 = B13 + ET1
   C11=EXP(A11)
   C12=EXP(A12)
   C13=EXP(A13)
   ;-----------------------------------------------------
   ; probabilities for Y>=1, Y>=2, Y>=3
   P11=C11/(1+C11)
   P12=C12/(1+C12)
   P13=C13/(1+C13)             
   IF (IND1A.EQ.0) THEN
      ;Probabilities for TRANSITION TO Y=0  Y=1, Y=2, Y=3 when it is beyond first transition
      PA1=1-P11
      PB1=P11-P12
      PC1=P12-P13
      PD1=P13
   ENDIF
   IF (IND1A.EQ.1) THEN
      ;Probabilities for TRANSITION TO Y=1, Y=2, Y=3 when it is FIRST transition
      PA1=1-P11
      ;CORRECT LIKELIHOOD SINCE ZERO CANNOT OCCUR HERE
      FUDG1=P11;1-PA1+.0000001
      ;IF (FUDG1.LE.0) EXIT 1 140
      PB1=(P11-P12)/FUDG1
      PC1=(P12-P13)/FUDG1
      PD1=P13/FUDG1
   ENDIF


 
 IF (IND1A.EQ.1) THEN
    FLG1=1
 ENDIF

   ;LIKELIHOOD FOR DATA PRIOR TO TRANSITION OUT OF AE=0 STATE
     IF (FLG1.EQ.0) THEN
       L=Q1
       ;IF (L.LE.0) EXIT 1 100
     ENDIF
;LIKELIHOOD FOR DATA AT TRANSITION OUT OF AE=0 STATE
     IF (FLG1.EQ.1.AND.IND1A.EQ.1.AND.DV.EQ.1) THEN
        L=(1-Q1)*PB1
        ;IF (L.LE.0) EXIT 1 200
     ENDIF

     IF (FLG1.EQ.1.AND.IND1A.EQ.1.AND.DV.EQ.2) THEN
        L=(1-Q1)*PC1
        ;IF (L.LE.0) EXIT 1 300
     ENDIF
     IF (FLG1.EQ.1.AND.IND1A.EQ.1.AND.DV.EQ.3) THEN
        L=(1-Q1)*PD1
        ;IF (L.LE.0) EXIT 1 400
     ENDIF

;LIKELIHOOD FOR DATA AFTER TRANSITION OUT OF AE=0 STATE
    IF (FLG1.EQ.1.AND.IND1A.EQ.0.AND.DV.EQ.0) THEN
      L=PA1
      ;IF (L.LE.0) EXIT 1 500
    ENDIF
    IF (FLG1.EQ.1.AND.IND1A.EQ.0.AND.DV.EQ.1) THEN
      L=PB1
      ;IF (L.LE.0) EXIT 1 600
    ENDIF
    IF (FLG1.EQ.1.AND.IND1A.EQ.0.AND.DV.EQ.2) THEN
      L=PC1
      ;IF (L.LE.0) EXIT 1 700
    ENDIF
    IF (FLG1.EQ.1.AND.IND1A.EQ.0.AND.DV.EQ.3) THEN
      L=PD1
      ;IF (L.LE.0) EXIT 1 800
    ENDIF


Y=L

   
   

   

$THETA

;AE1 STRUCTURAL PART
 (0,0.319)          ;1 ALPHA TTFAE1 SHAPE
 (0,.117)          ;2 SECOND ALPHA TTFAE1 SHAPE
 (0,15300)          ;3 MEDIAN TTFAE1 
 (0,0.99)       ;4 TDOS EMAX ON TTFAE1 MEDIAN
 (0,13.9)           ;5 TDOS ED50 ON TTFAE1 MEDIAN
 ( 6 FIX)           ;6 GAM1 ON TTFAE1 MEDIAN 
 (0,6,15)          ;7 CHANGE POINT FOR TTFAE1
 (1.78)          ;8 B1 PAE1=0
 (-10,-1.397,0)         ;9 B2 PAE1=0
 (-10,-1.96,0)          ;10 B3 PAE1=0
 (1.78)           ;11 B1 PAE1=1
 (-10,-1.2,0)          ;12 B2 PAE1=1
 (-10,-1,0)        ;13 B3 PAE1=1
 (1.52)           ;14  B1 PAE1=2
 (-10,-0.187,0)         ;15  B2 PAE1=2
 (-10,-1.8,0)          ;16  B3 PAE1=2
 (2.48)           ;17 B1 PAE1=3
 (-10,-0.67,0)     ;18 B2 PAE1=3
 (-10,-2.108,0)         ;19 B3 PAE1=3
 (1 FIX)          ;20 JD ON ETA1
$OMEGA 2
;$SIM (4321) (321 UNIFORM) ONLYSIMULATION NOPREDICTION SUBPROBLEMS=1
$EST METH=1 LAPLACE LIKE MAXEVALS=9999 PRINT =1 NOABORT SIG=3
$COV PRINT=E MATRIX=R
;$TABLE ID ETA1 NOAPPEND NOHEADER NOPRINT FIRSTONLY FILE=T402A.TXT